Cours complet pour apprendre à programmer un Arduino

////////// Déclaration des variables
const int CAPTEUR = A0;     // le Piezo est connecté à la pin Analogue 0
int lectureCapteur = 0;     // variable pour stocker la valeur du capteur
const int LED = 13;         // LED connectée à la broche digitale 13
const int SEUIL = 1;        // choix du seuil de détection
const int ANTIREBOND = 600; // choix du filtre anti-rebond
long temps = 0;             // variable pour mémoriser le temps

////////// Initialisation
void setup() {
    pinMode(LED, OUTPUT); // définir la pin associée à LED comme sortie
    Serial.begin(9600);   // configurer le port série
}

////////// Boucle principale
void loop() {
    // lecture de la valeur du Piezo
    lectureCapteur = analogRead(CAPTEUR);
    // si la valeur captée est supérieure au seuil choisi et
    // que le temps écoulé depuis le dernier impact est
    // supérieur au temps de l'ANTI-REBOND,
    // alors on rentre dans la condition
    if (lectureCapteur >= SEUIL && millis() - temps >= ANTIREBOND) {
        // envoi de l'information à l'ordinateur
        Serial.println("impact");
        temps = millis(); // mise à jour du temps courant
    }
    else {
        // on ne fait rien
    }
}

if (lectureCapteur >= SEUIL && millis () - temps >= ANTIREBOND) {
    ...
}

if (marqueurTemps [posTableau] == 0 || posTableau == NOMBREMARQUEURS) {
    ...
}

////////// Déclaration des variables
// ces variables sont constantes
const int LED = 13;             // LED connectée à la pin digitale 13
const int CAPTEUR = A0;         // Piezo connecté à la pin Analogue 0
const int SEUIL = 1;            // seuil de détection du capteur
const int ANTIREBOND = 200;     // filtre anti-rebond
const int FIN = 2000;           // temps pour définir la fin du mode écoute
const int NOMBREMARQUEURS = 50; // nombre maximum de marqueurs temps

// ces variables changent
int lectureCapteur = 0;              // valeur du capteur
int ledEtat = LOW;                   // état de la LED
int mode = 1;                        // mode écoute (1) ou jeux (2)
int posTableau = 0;                  // Position dans le tableau
long temps = 0;                      // variable pour mémoriser le temps
long marqueurTemps[NOMBREMARQUEURS]; // tableau pour mémoriser les temps qui séparent chaque impacte
int i = 0;                           // variable pour parcourir la liste

boolean DEBUG = false;       // activer ou non le DEBUG
boolean BOUCLE = false;      // TODO

void setup() {
    pinMode(LED, OUTPUT);     // déclarer la pin en sortie
    Serial.begin(9600);       // configurer le port série
}

////////// Boucle principale
void loop() {
    switch(mode) {
    case 1: // mode enregistrement
        if(DEBUG == true) Serial.println("mode 1"); // envoi du mode
        // lecture de la valeur du capteur Piezo
        lectureCapteur = analogRead(CAPTEUR);

        // si la valeur captée est supérieure au seuil choisi et
        // que le temps écoulé depuis le dernier impact est supérieur au temps de l'ANTIREBOND
        // alors on rentre dans la condition
        if (lectureCapteur >= SEUIL && millis() - temps >= ANTIREBOND) {
            marqueurTemps[posTableau] = millis() - temps; //
            digitalWrite(LED, HIGH);  // activer la broche de la LED
            delay(5);                 // attendre 10 millisecondes
            digitalWrite(LED, LOW);   // éteindre la broche de la LED
            // on mémorise le temps écoulé entre chaque impact
            posTableau++;             // on incrémente la position
            temps = millis();         // initialisation
        }

        // si le temps écoulé depuis le dernier impact est supérieur
        // au temps dit de FIN et que plus de deux impacts sont enregistrés
        // alors on rentre dans la condition
        if (millis() - temps >= FIN && posTableau >= 2) {
            posTableau = 0;             // initialiser la position
            mode = 2;                   // choisir le mode 2
            if (DEBUG == true) Serial.println("mode 2"); // envoi du mode
            temps = millis();           // initialisation du temps
        }

        break;                        // sortir du mode 1

    case 2: // mode de jeux
        // lecture de la valeur du capteur Piezo
        lectureCapteur = analogRead(CAPTEUR);
        // si la valeur du capteur est supérieure au seuil
        // alors on entre dans la condition puisque l'usager rejoue
        if (lectureCapteur >= SEUIL) {
            // on efface toutes les valeurs du tableau
            for (i=0; i<NOMBREMARQUEURS; i++) {
                marqueurTemps[i] = 0;
            }
            posTableau = 0;    // initialiser la position
            mode = 1;          // choisir le mode 1
            if (DEBUG == true) Serial.println("mode 2 stop"); // envoi du mode
            temps = millis();  // initialisation du temps
            break;             // sortir du mode 2
        }

        // si la valeur de temps stockée dans le tableau n'est pas nulle
        // et que cette valeur de temps est dépassée par le conteur millis()
        // alors on entre dans la condition
        if ( marqueurTemps[posTableau] != 0 && millis() - temps >= marqueurTemps[posTableau] ) {
            digitalWrite(LED, HIGH);   // activer la broche de la LED
            delay(5);                  // attendre 5 millisecondes
            digitalWrite(LED, LOW);    // éteindre la broche de la LED
            posTableau++;              // on incrémente la position
            temps = millis();          // initialisation du temps
        }

        // si la valeur de temps stockée dans le tableau est nulle
        // ou que nous arrivons à la fin du tableau
        // alors on entre dans la condition
        if ( marqueurTemps[posTableau] == 0 || posTableau == NOMBREMARQUEURS ) {
            for (i=0; i<NOMBREMARQUEURS; i++) { // on efface toutes les valeurs du tableau
                marqueurTemps[i] = 0;
            }
            posTableau = 0;     // initialiser la position
            mode = 1;           // changer de mode
            if(DEBUG == true) Serial.println("mode 2 end"); // envoi du mode
            temps = millis();   // initialisation du temps
        }
        break;                // sortir du mode 2
    }
}

int posTableau = 2; // initialisation de posTableau à 2
long val = 127; // initialisation de val à 127

marqueurTemps [Position] = valeur;

int posTableau = 2; // initialisation de posTableau à 2
int val = 0; // initialisation de val à 0

val = marqueurTemps [posTableau];